Classical Free Fall Calculation

This Mathematica Notebook performs the calculation of the time of free fall from the orbit of the Earth to the Sun, using simple Newtonian functions.

Glen Langston,  NRAO GB, 2004 October 1

Clear[ GM,  Φ,  r,  t,  
      m,  v,  A]

The Newtonian Acceleration of a particle in free fall is the derivative of the potential

Φ[r_]  :=  GM /r

During Free Fall, energy is conserved, so falling at rest from A to r yields

SetAttributes[A,  Constant]

Energy =  
      m v^2/2   -  
          m Φ[r]  ==  - m Φ[
            A]

V  = Solve[ Energy,  v]

f  =  1/(v /. V[[1]])

Now work with the special case of falling from rest at 1 AU towards the Sun

A  =  1

Calculate the function, T[r], the time it takes a particle to fall from rest at 1 AU, to a ratius r. The Integral function of a freely falling particle is surprisingly complicated:

T  = Integrate[ f,  r]

Now calculate the duration of the fall from the limits at one AU and zero AU.

AB  = Simplify[ Limit[ T,  r -> 1]]

AA  =  Simplify[ Limit[ T,  r -> 0]]

N[AA]

Calculation Units: Conversion to Days

The Distance Units for this calculation are AU.  The time units for this calculation are days.  In these units, GM is a small number, indicating that the system is not relativistic.  GC = gravitational constant = 6.67300 × 10^-11 m3 kg^-1 s^-1; Astronomical Unit = 149 598 000 000;  One Day = 86400 s

GC  =  6.673 10^-11 m^3/kg/s^2

MS  =  1.9891  10^30 kg

AU  =  1.49598 10^11 m

day  =  3600 24  s

Calculate the Speed of Light in AU per day (Its a fairly small number)

clight  =  (299782458 m/s )  (day / AU)

The Distance Units for this calculation are AU.  The time units for this calculation are days.  In these units, GM (gm) is a small number, indicating that our solar system is not general-relativistic.

gm  = GC MS day^2/ AU^3

Formally, the velocity of the particle goes to infinity as r goes to zero.  To avoid this, the calculation will stop at the Solar Radius (RS).   The Sun can not be treated as a point source inside a Solar Radius anyway.

RS  =  6.95987 10^8 m

In Astronomical Units (AU) the Solar Radius is 0.47 % of an AU.

rs  =  RS / AU

MaxT  = Limit[ AA,  GM   ->  gm]

Now numerically evaluate the time,  T in days,  
    it takes an object to fall from rest from 1 AU to the surface of the Sun.

MaxT  = 
      Abs[Limit[ Limit[T,  r -> rs],  GM   ->  gm]]

Calculation of the Speed: v[r]

T

t[r] is the time to fall a distance r(AU) in units of days

t  =  Limit[ T,  GM  ->  gm]

Plot[ t,  {r,  rs,  1},  
      AxesLabel -> {"Distance/AU",  "T/days"}]

Calculate the speed of the falling object in units of the speed of light.

OneOverV  =  D[ t,  r]

v  =  1/OneOverV

Plot[ v,  {r,  rs,  1},  
      AxesLabel ->  { "Distance/AU",  "Velocity \
(AU/day)"}]

The velocity is negative because it is the infall velocity .   The magnitude of the velocity is:

mag  :=  Abs[v]/clight

\(\(\(Plot[\ mag, \ {r, \ rs, \ 1}, \ 
      AxesLabel -> \ {\ "Distance/AU", \ "β / c"}]\)\(
\)
    \)\)

The maximum velocity is the velocity when reaching the surface of the Sun (in units of c).

MaxMag  =  Abs[Limit[ mag,  r -> rs]]

Converting  back to km/s

MaxMag 299782.458 km/s